Ein Pflanzenwächter für die Fensterbank - AZ-Delivery

Heute möchte ich euch ein neues interessantes mehrteiliges Projekt mit dem vielseitigen und leistungsfähigen ESP 32 vorstellen. Wir bauen uns einen Pflanzenwächter für unsere heimischen Pflanzen. Dieser soll während wir unsere Aufmerksamkeit unseren spannenden Elektronikprojekten widmen, den Wassergehalt der Pflanzenerde überwachen und uns darüber informieren, wenn die Bodenfeuchte sinkt. Dazu hat unser Pflanzenwächter eine LED-Ampel, die bei feuchter Erde grün leuchtet und bei trockener Erde über gelb rot wird. Bevor wir jedoch mit dem Projekt beginnen, müssen wir uns jedoch noch, vor dem eigentlichen Start des Projektes einige Gedanken machen. Dies betrifft insbesondere den Einsatz des Pflanzenwächters. Da unser Pflanzenwächter die Feuchtigkeit der Erde über eine kapazitive Nahfeldmessung bestimmt, ist es notwendig, dass die Feuchtigkeit in unmittelbarer Nähe des Sensors gespeichert wird. Während i.d.R. normale (Blumen-)Pflanzenerde aus dem Baumarkt oder dem Supermarkt diese Bedingung erfüllt, ist dies bei u.a. Hydrokultursubstraten oder Orchideensubstrat nicht der Fall! Daher:

Dieses Projekt ist für Hydrokulturpflanzen oder Luftwurzlerpflanzen (wie z.B. Orchideen) nicht geeignet!

Außerdem haben Pflanzen ganz unterschiedliche Anforderungen an Ihre Bewässerung. Während mache Pflanzen eine dauerhafte Grundfeuchte (meistens keine Staunässe) bevorzugen, sind mache dagegen eher trockenliebend und möchten nur selten gegossen werden. Da die individuellen Anforderungen der Pflanze unser Pflanzenwächter nicht kennen kann, liegt die Interpretation der nötigen Aktionen (gießen oder nicht gießen) auf die (Ampel-) Anzeige des Pflanzenwächters ausschließlich in der Hand des botanisch kundigen Anwenders 😊. 

Der Pflanzenwächter ist daher kein Ersatz für eine verantwortungsvolle- und pflanzengerechte Pflege deiner Pflanzen!

Im weiteren Verlaufe des Projektes und mit größer werden dem Umfang werden wir weitere Sensoren anbinden und natürlich auch Komfortfunktionen hinzufügen. Lasst euch überraschen!
Aber fangen wir mit der Basis an. Schauen wir uns die Bauteile an, die wir für unseren Pflanzenwächter für den Anfang brauchen:

  • 1 x LED Farbe Grün (560nm); 5 mm
  • 1x LED Farbe Gelb (605nm); 5 mm
  • 1x LED Farbe Rot (633nm); 5 mm
  • 6x130kΩ Widerstand Toleranz ±1%;
  • 6x 47kΩ Widerstand Toleranz ±1
  • 3x 150Ω Widerstand Toleranz ±1%;
  • 1x Kapazitiver Feuchtesensor
  • 1x ESP32-38Pin Variante Generic; Typ NodeMCU-32S; Beinchen 38;
  • 1x YwRobot Breadboard Spannungsversorgung

Wir verdrahten die Komponenten wie folgt:

Schaltung

 

Die 150 Ohm Widerstände werden als Vorwiderstände für die LEDs genutzt. Der 130 KOhm bildet zusammen mit dem 47 KOhm Widerstand ein Spannungsteiler für den Analogausgang des Feuchtigkeitssensors.

Wir laden folgenden Code auf unseren ESP32 hoch:

Sketch Download

#include <driver/adc.h>

// Portedefinierung Led's
#define LED_Rot     5     // Rote LED 
#define LED_Gelb    14    // Gelbe LED
#define LED_Gruen   15    // Gruene LED

// LED PWM Einstellungen
#define PWMfreq 5000  // 5 Khz basisfrequenz
#define PWMledChannelA  0
#define PWMledChannelB  1
#define PWMledChannelC  2
#define PWMresolution  8 // 8 Bit Resolution
#define ADCAttenuation ADC_ATTEN_DB_11  //ADC_ATTEN_DB_11 = 0-3,6V  Dämpung ADC Einstzellung
#define MaxSensors 1


struct MoistureSensorCalibrationData
{
  int Data[MaxSensors * 2] = {0, 0}; // Calibration Data für Feuchtigkeitssensor. Bitte Projekt Text beachten und Werte ensprechend anpassen
};

struct MoistureSensorData
{
  byte Percent[MaxSensors] = {0};  // Feuchtigkeitssensordaten in Prozent
};

//Global Variables
MoistureSensorCalibrationData MCalib;
MoistureSensorData MMeasure;
byte AttachedMoistureSensors; // Detected Active Moisture Sensors (Count)

void setup() {
  // initialize serial communication at 9600 bits per second:
  pinMode(LED_Rot, OUTPUT);
  pinMode(LED_Gelb, OUTPUT);
  pinMode(LED_Gruen, OUTPUT);
  Serial.begin(115200);
  ledcSetup(PWMledChannelA, PWMfreq, PWMresolution);
  ledcSetup(PWMledChannelB, PWMfreq, PWMresolution);
  ledcSetup(PWMledChannelC, PWMfreq, PWMresolution);
  ledcAttachPin(LED_Rot, PWMledChannelA);   // attach the channel to the GPIO to be controlled
  ledcAttachPin(LED_Gelb, PWMledChannelB);
  ledcAttachPin(LED_Gruen, PWMledChannelC);
  SetLedConfig(20, 20, 20);
  AttachedMoistureSensors = DetectMoistureSensors();
  Serial.println(F("Systemkonfiguration:"));
  Serial.print(AttachedMoistureSensors);
  Serial.println(F(" Bodenfeuchtigkeitsensor(en)"));
}

byte DetectMoistureSensors ()
{
#define MinSensorValue 100
  byte Detected = 0;
  for (int i = 0; i < MaxSensors; i++)
  {
    int MSensorRawValue = ReadMoistureSensorVal(i);
    if ( MSensorRawValue > MinSensorValue) {
      Detected++;
    } else {
      break;
    }
  }
  if (Detected < 1)
  {
    Serial.println(F("Keine Bodenfeuchtigkeitssesoren erkannt. System angehalten."));
    esp_deep_sleep_start();
    while (1) {}
  }
  return Detected;
}

bool SetLedConfig(byte Red, byte yellow, byte green)
{
  ledcWrite(PWMledChannelA, Red); // Rote LED
  ledcWrite(PWMledChannelB, yellow); // Gelbe LED
  ledcWrite(PWMledChannelC, green); // Gruene LED
  return true;
}

int ReadMoistureSensorVal(byte Sensor)
{
  int ReturnValue, i;
  long sum = 0;
#define NUM_READS 6
  adc1_config_width(ADC_WIDTH_BIT_12);   //Range 0-4095
  switch (Sensor)
  {
    case 0:
      {
        adc1_config_channel_atten(ADC1_CHANNEL_0, ADCAttenuation);
        for (i = 0; i < NUM_READS; i++) { // Averaging algorithm
          sum += adc1_get_raw( ADC1_CHANNEL_0 ); //Read analog
        }
        ReturnValue = sum / NUM_READS;
        break;
      }
  }
  return ReturnValue;
}

bool GetMoistureData()
{
  bool ReadisValid = true;
  for (int i = 0; i < AttachedMoistureSensors; i++)
  {
    if ((MCalib.Data[i] == 0) || (MCalib.Data[i + 1] == 0)) // MinADC Value maxADC ADC Value
    {
      ReadisValid = false;
      return ReadisValid;
    }
    int RawMoistureValue = ReadMoistureSensorVal(i);
    RawMoistureValue = MCalib.Data[i + 1] - RawMoistureValue;
    RawMoistureValue = MCalib.Data[i] + RawMoistureValue;
    MMeasure.Percent[i] = map(RawMoistureValue, MCalib.Data[i], MCalib.Data[i + 1], 0, 100);
    if (MMeasure.Percent[i] > 100 ) {
      ReadisValid = false;
    }
  }
  return ReadisValid;
}

// Main Loop
void loop()
{
  if (GetMoistureData())
  {
    Serial.print(F("Feuchtigkeitswert Sensor 1 in Prozent :"));
    Serial.print(MMeasure.Percent[0]);
    Serial.println(F(" %"));
    if (MMeasure.Percent[0] > 50)
    {
      SetLedConfig(0, 0, 20);
    }
    else if (MMeasure.Percent[0] > 10)
    {
      SetLedConfig(0, 255, 0);
    }
    else
    {
      SetLedConfig(255, 0, 0);
    }
  }
  else
  {
    Serial.print(F("Bodenfeuchtigkeitssensor nicht kalibriert.Bitte kalibrieren. RohDaten des Sensors 1:"));
    Serial.println(ReadMoistureSensorVal(0));
    SetLedConfig(20, 20, 20);
  }
  delay(1000);        // delay between reads for stability
}

Als letzten Schritt müssen wir nun die Kalibrierung unseres Feuchtigkeitssensors durchführen. Die Kalibrierung des Sensors legt fest, was als trockene Erde (Wassergehalt 0%) und was nasse Erde (Wassergehalt 100%) erkannt wird. Dazu strecken wir den Feuchtigkeitssensor als erstes in absolut trockene Erde und lassen uns die Sensor-Rohdaten auf der seriellen Schnittselle ausgeben:

 

Wert 1: (Trocken)

Bodenfeuchtesensor nicht kalibriert

Wir notieren uns den Wert (2276) und bewässern nun die Erde solange, bis sie komplett! durchnässt ist und kein Wasser mehr ausnehmen kann. Wir notieren uns den Wert 2: (Nasse Erde) (1648)

Wert bei Nässe

 

Wir addieren zu dem ersten Wert 2276, 10 dazu und ziehen von 1648, 10 ab. Es ergeben sich daraus die Werte 2286 und 1638

Wir tragen die Werte in unseren Code ein:

struct MoistureSensorCalibrationData

{
int Data[MaxSensors*2] = {1638,2286};
};

Und laden den Code erneut hoch.

Wir erhalten folgende Ausgabe:

Ausgabe Bodenfeuchte

 

Gleichzeitig zeigt unsere Led „Ampel“ grün an. Dabei bedeuten die Farben:

Grün: Feuchtigkeit hoch.

Gelb: Feuchtigkeit mittelmäßig. 

Rot: Trocken.

Viel Spaß beim Nachbauen und bis zum nächsten Teil der Serie.

Esp-32Projekte für fortgeschritteneSensorenSmart home

19 Kommentare

Andreas Wolter

Andreas Wolter

@Rolf: Danke für die Info. Ich habe das eben in anderen Blogs getestet und es scheint ein globales Problem zu sein.
Ich habe hier in diesen Beitrag einen Download Link hinzugefügt. Ich gebe das an die technische Abteilung weiter und hoffe, dass das Problem behoben wird.

Grüße,
Andreas Wolter
AZ-Delivery Blog

Rolf

Rolf

Hallo,
ich weiss nicht, ob es bekannt ist: wenn man den Sketch über den Button Ziwschenablage kopiert, werden jeweils ab dem 2. Leerzciehn infolge nicht Hex 20 sondern Hex A0 eingefügt. Das stört den Adrduino Überseteer mit der Bemerkung “extended character is not vaid in an identifier”
Kann einen zur Verzweiflung bringen!
Wenn man es mit Markieren mit der Masu via Zwischenablage erledigt, ist alles ok.
mfg

Patrick

Patrick

Super, dass du mit uns dein Projekt teilst. Vielen Dank dafür!

Ich habe eine Frage bezüglich der Spannungsversorgung: Würde die Spannungsversorgung vom ESP32 auch alleine ausreichen? Wie hoch darf der maximale Laststrom sein? Ich finde dazu leider keine Angaben.

Viele Grüße
Patrick

Tobias Kuch

Tobias Kuch

Hallo Clajo,
Die Antwort auf die Frage wie lange die Zuleitungen zu dem Sensor sein dürfen ist nicht trivial und hängt von einigen Faktoren ab. Diese ergeben sich aus dem Grundsatz bzw. der Formel des Spannungsabfalls auf elektrischen Leitungen. Die Antwort auf deine Frage ergibt sich aus den Formeln R (Leitung)=2L/κ (Kupfer κ = 56,0)* A und ΔU=R⋅I Davon ausgehend, das die Betriebsspannung Ub Nom. 5 Volt des NE555 Timers nicht mehr als 0,5 Volte abfallen sollte bei 0,2 A angenommenen Strombezug ergibt sich durch einsetzen ein max. R von 2,5 Ohm. Umgestellt nach Leitungslänge bei ang. materialabhängige Leitfähigkeit von Kupfer und angenommenen 1mm Querschnitt des Kabels ergibt sich durch Umstellung eine Maximallänge von L = 70 Meter. Die parasitäre Kapazität der Leitung ist irrelevant, da diese erst bei hohen Freuenzen von belang ist.. Ich hoffe, dein Frage zufriedenstellend beantwortet zu haben

Clajo

Clajo

Hallo,

wie lang darf die Leitung vom Sensor bis zum Board sein?
Jörg

Tobias

Tobias

Hallo Jörg,

Die Idee mit der Ansteuerung für eine automatische Bewässerung währe zwar eine konsequente Erweiterung , würde jedoch den Rahmen des Projektes hier sprengen. Falls du weitergehende Tipps dazu bekommen möchtest, schreibe bitte an AZ-Delivery mit bitte um Weiterleitung an mich. Dann gehe ich gerne zu diesem Thema noch auf Details ein.

Jörg

Jörg

Hi Tobias,
dein Hinweis auf ein gewisses Grundwissen der Programmierung ist schon nicht falsch.
Zumindest weiß ich in der Zwischenzeit auch wie das mit der Belegung der Pins in der Programmierung zu erkennen ist. Wenigstens ein kleiner Lichtblick für mich…..
Denn in meinem Alter will ich nicht mehr großartig anfangen irgend welche Programmiersprachen zu lernen, das Grundlegende des Code verstehe ich soweit ich weiß um was es sich dabei handeln soll….
Jetzt aber gleich noch eine ganz einfache Frage:
Ich habe ein ähnliches Projekt aber das läuft auf einer separaten Hardware und nennt sich: Gies-O-Mat mit AVR
Vom Prinzip her das gleiche Grundprinzip, kapazitive Feuchtigkeitssensoren zur Ermittlung der Erdfeuchte. Nur kann dieses Projekt nun auch noch Relais ansteuern und somit die Pflanzen selbständig gießen…….
Denkst du dass du das vielleicht auch noch implementieren könntest, dann wäre das ganze Projekt ja absolut unschlagbar ?!?!?

Tobias

Tobias

Hallo Jörg,

Erst einmal vielen Dank für die Beantwortung der Fragen bzgl. des Treibers. Du liegst natürlich direkt richtig. Der Treiber wird automatisch eingebunden. Bezüglich des Schaltbildes würde ich dich bitten, etwas Geduld zu haben. Ich werde dieses bei Gelegenheit dann auf meiner GIT-Hub Seite auf https://github.com/kuchto auf der ich die Projekte ebenfalls einstelle, veröffentlichen. Dieses Projekt setzt aber Erfahrung in der Technik an sich als auch in der Programmierung voraus.

Knut Dorendorff

Knut Dorendorff

Hallo Jörg. Vielen Dank für die Hinweise. Ich habe zwar noch nicht die einzelnen Teile zusammen gesteckt, aber zunächst hatte ich auch mit der Ansicht Probleme. Allerdings muss du berücksichtigen, dass auf dieser Seite nur ein Sensor angeschlossen ist, aber die Vorbereitung für weitere 5 Sensoren schon verbaut sind, aber noch nicht genutzt werden. Siehe am unteren Bild die Widerstände. Wenn Du in den dritten Teil gehst sollte es sich erklären.
Schauen wir mal .
Gruß Knut

Jörg

Jörg

Hallo Knut,
das Problem mit dem Treiber hat sich, denk ich mal von selbst erledigt.
Sobald man nämlich das Board ESP32xxxxx verwendet, wird auch automatisch der richtige Treiber bereit gestellt.
Zumindest habe ich das bisher bei der Überprüfung beim Kompilieren festgestellt.
Falls das nicht stimmen sollte:
Bitte nicht gleich alle mit dem Vorschlaghammer auf mich einschlagen ;-))))
Und in einem anderem Thread habe ich lesen können dass dieser Sketch nicht mit dem Lolin V3 kompatibel ist, somit hat sich diese Frage auch schon von selbst aufgelöst.
Das Einzige:
Ich kann die Schaltung nach wie vor nicht richtig erkennen….
Gibt es hierfür einen schöneren Steckplan oder gar Schaltplan?

Jörg

Knut Dorendorff

Knut Dorendorff

Halli Hallo,
eine tolle Sache. Wie komme ich an Library Driver/adc.h ?

Gruss Knut.

Knut Dorendorff

Knut Dorendorff

Große Klasse. Allerdings habe ich auch das Problem wie Jörg, dass die Library Driver/adc.h nicht gefunden wird. Wo bekomme ich die als Zip?

Gruß Knut

Jörg

Jörg

Hallo, eine sehr schöne Schaltung welche ich gerne auch nachbauen möchte.
Leider bin ich nicht gerade der Programmierprofi und habe auch mit der Beschaltung an sich ein kleines Problem. Ein paar Fragen hierzu:
1.: Gibt es eine Art Schaltplan für diese Schaltung, ich kann das Bild sehr schlecht erkennen ?
2.: Kann man diese Schaltung auch mit einem Lolin NodeMcu V3 nachbauen ?
3.: Wo finde ich den Treiber <driver/adc.h> ?

Jörg

Tobias Kuch

Tobias Kuch

Hallo Thorsten,

In dem von dir genannten Datasheet wird eine Minimalbertriebsspannung von 3,0 volt genannt. Bei einer Betriebsspannung des Sensors von 3,0 Volt ist die Ausgangsspannung tatsächlich Betriebsbedingt 3 volt. Der Sensor funktionierte bei mir in Tests jedoch erst zuverlässig mit 5 Volt. Im Schaltbild siehst du auch das er auf der 5 Volt Schiene liegt. GEMESSENE Ausgangsspannung war bei trockenem Sensor bei mir dann 4 Volt. Also zu hoch für den ESP. Daher ist und bleibt der Spannungsteiler notwendig ;)

Thorsten

Thorsten

Das mit dem Spannungsteiler ist mir nicht ganz logisch. Der Sensor hat einen Ausgangsspannungsbereich von 0V bis 3.0V (https://media.digikey.com/pdf/Data%20Sheets/DFRobot%20PDFs/SEN0193_Web.pdf) und damit innerhalb der Spec vom ESP.

Wäre nett, wenn du das noch mal klarstellen würdest.

Thorsten

Tobias

Tobias

Hallo Joe,

Es werden keine kapazitiven Werte durch den ESP gemessen, sondern, bedingt durch die interne Funktionsbeschaltung des Feuchtesensors, analoge Gleichspannungswerte. Da der Messbereich des ESP jedoch unterhalb der max. . analogen Spannungswerte des Feuchtesensors sind , ist der Spannungsteiler notwendig.

Tobias

Tobias

Hallo Paulaner,

Die Beschaltung der Wiederstände ist nicht mangelhaft, sondern im Gegenteil Absicht sind, da diese , und auch der Code bereits Vorbereitungen für die Anbindungen weiterer 5 Sensoren des Typs Feuchtesensoren enthalten bzw. sind.

paulaner

paulaner

Hallo,
ihr Fritzing Bild ist mangelhaft, 5 Widerstände hängen in der Luft, nix Spannungsteiler.
H. Winkler

joe

joe

Ganz logisch erscheint mit die Beschaltung des Spannungsteiler und Feuchtesensor nicht.
Das ich bei Messung kapazitiver Werte ein Wechselspannung mit einer, entsprechen dem kapazitiven Wert des Sensor, Frequenz betreiben muß. Das sehe ich dort nicht.

Kommentar hinterlassen

Alle Kommentare werden von einem Moderator vor der Veröffentlichung überprüft

Empfohlene Blogbeiträge

  1. ESP32 jetzt über den Boardverwalter installieren - AZ-Delivery
  2. Internet-Radio mit dem ESP32 - UPDATE - AZ-Delivery
  3. Arduino IDE - Programmieren für Einsteiger - Teil 1 - AZ-Delivery
  4. ESP32 - das Multitalent - AZ-Delivery