Die sprechende Uhr

L'article d'aujourd'hui porte sur une autre méthode d'affichage du temps et des valeurs mesurées, à savoir la sortie vocale. Une possibilité simple pour la sortie vocale est d'enregistrer des fichiers MP3 pour des mots isolés. Le résultat peut alors être composé à partir de ces mots. Pour la lecture, un mini lecteur MP3 peut être utilisé, qui lit ensuite les fichiers MP3 à partir d'une carte Micro SD.

Matériel requis

Nombre

Composant

Annotation

1

NodeMCU Lua Lolin V3


1

Mini lecteur MP3


1

GY-BME280


1

Mini haut-parleur 8 ohms


1

Elko 1000 à 2200 µF / 10V


2

Micro bouton



Circuit

Pour le DFPlayer, nous avons besoin, outre l'alimentation électrique, d'une connexion à une interface série. Nous choisirons une solution logicielle comme interface série, afin de pouvoir choisir librement les broches utilisées. Pour la ligne d'envoi du microcontrôleur vers le DFPlayer, nous utilisons le GPIO14, marqué D5. Pour la direction opposée, nous utilisons le GPIO12, étiqueté D6. Nous connectons le mini haut-parleur directement aux sorties du DFPlayer. La ligne plus est indiquée en orange, la ligne moins en bleu clair.

Comme il y a de courtes pointes de courant au début de la lecture, vous devez connecter un condensateur électrolytique en parallèle à la tension d'alimentation pour éviter les interférences. Le capteur BME280 fonctionne avec l'I2CBus. Les broches par défaut sont GPIO5/D1 pour l'horloge (SCL) et GPIO4/D2 pour les données (SDA). Nous connectons le bouton pour sortir l'heure sur GPIO0/D3 et la masse. Le bouton pour sortir les lectures du capteur avec GPIO2/D4. Si vous voulez seulement l'horloge, vous pouvez omettre le capteur et le second bouton. Un autre capteur peut également être utilisé. Dans les deux cas, le programme doit être modifié en conséquence.


Cela étant fait, le câblage est terminé et nous pouvons poursuivre le programme.

Programme

Comme nous voulons obtenir la date et l'heure d'un serveur de temps NTP sur l'internet, nous avons besoin d'une connexion internet. Cela peut être établi très facilement avec la ESP8266.

Pour le BME280, nous utilisons la bibliothèque "BlueDot_BME280.h", que nous pouvons installer via la gestion de la bibliothèque Arduino.
Pour la sortie vocale, nous utilisons la bibliothèque Talking_Display.h, que j'ai développée spécialement pour la sortie vocale avec le DFPlayer. Cette bibliothèque devrait également être installable via la gestion de la bibliothèque Arduino. Cette bibliothèque a plusieurs fonctions pour une sortie vocale simple :

void say (uint16_t word_index)
Le numéro est édité avec un signe. Des nombres compris entre -2147483647 et 2147483647 sont possibles.

void sayInt (nombre int32_t)
Le nombre est affiché avec un signe. Les nombres compris entre −2147483647 et 2147483647 sont possibles.

void sayFloat (nombre flottant, décimales uint8_t)
Le nombre est édité avec le signe et les décimales. On ne peut choisir qu'une ou deux décimales. Les valeurs pour les décimales inférieures à deux se traduisent par 1, les valeurs supérieures ou égales à deux se traduisent par deux. La plage de valeurs va de -2147483647,99 à 2147483647,99.

void sayTime (struct tm * structure de temps, bool Format24, bool seconds)
Le temps représenté par la structure temporelle est la sortie. Si l'argument Format24 est vrai, le format 24 heures est utilisé, sinon le format 12 heures avec le matin et l'après-midi. Si l'argument secondes est vrai, les secondes sont sorties, sinon elles sont omises.

void sayDate (struct tm * structure de temps, booléen jour de semaine, année booléenne)
La date représentée par la structure temporelle est sortie. Si l'argument du jour de la semaine est vrai, le jour de la semaine est produit en premier, sinon non. Si l'année de l'argument est vraie, l'année est la production, sinon elle est omise.


#include <ESP8266WiFi.h>      //WLAN Unterstützung
#include <TZ.h> //Zeitzonen Konstanten
#include <SoftwareSerial.h> //Serielle Schnittstelle
#include <Talking_Display.h> //Sprachausgabe
#include <Wire.h> //Kommunikation für I2C
#include <BlueDot_BME280.h> //Bibliothek für den Sensor


//SSID und PSK vom lokalen WLAN
#define STASSID "****************"
#define STAPSK "****************"

#define BTN1 0 //Pin für den Knopf zur Zeitausgabe
#define BTN2 2 //Pin für den Knopf zur Ausgabe der Sensorwerte

#define DFPLAYER_RX 12 //RX Anschluss für die Kommunikation mit dem DFPlayer
#define DFPLAYER_TX 14 //TX Anschluss für die Kommunikation mit dem DFPlayer

//Zeitzone mit Sommer/Winterzeit Information
#define MYTZ TZ_Europe_Berlin
//Internet Zeitserver
#define NTP_SERVER "pool.ntp.org"

//Instanz der seriellen Schnittstelle
SoftwareSerial ss(DFPLAYER_RX,DFPLAYER_TX); // RX, TX
//Instanz für die Sprachausgabe
Talking_Display<SoftwareSerial> td(ss);
//Instanz für den Sensor
BlueDot_BME280 bme; //Ausgabe von Uhrzeit und Datum
void speak() {
time_t now = time(nullptr); //aktuelle Zeit
struct tm * s_time = localtime(&now); //Zeitstruktur aufgesplittet in Jahr, Monat, Tag, Stunden, Minuten und Sekunden
td.sayDate(s_time,true,false); //Datum ausgeben mit Wochentag aber ohne Jahr
td.sayTime(s_time,true,true); //Zeit ausgeben mit 24-Stunden Format und Sekunden
}

//Ausgabe der Meßwerte vom Sensor
void speakSensor() {
float temp,hum,pr;
temp = bme.readTempC(); //Temperatur lesen
hum = bme.readHumidity(); //Luftfeuchtigkeit lesen
pr = bme.readPressure(); //Luftdruck lesen
//Kontrollausgabe auf der seriellen Schnittstelle
Serial.printf("Temp %4.1f °C Hum %4.1f %% Pr %6.1f hPa \n",temp,hum,pr);
//Ausgabe der Temperatur mit 1 Kommastelle
td.say(WORD_TEMPERATURE);
td.sayFloat(temp,1);
td.say(WORD_DEGREE); td.say(WORD_CELSIUS);
//Ausgabe der Luftfeuchtigkeit mit 1 Kommastelle
td.say(WORD_HUMIDITY);
td.sayFloat(hum,1);
td.say(WORD_PERCENT);
//Ausgabe des Luftdruckes mit 1 Kommastelle
td.say(WORD_AIR_PRESSURE);
td.sayFloat(pr,1);
td.say(WORD_HECTOPASCAL);
}

//Callback Funktion für Felermeldungen vom DFPlayer
void tdError(String msg) {
Serial.println(msg);
} //Setup Funktion
void setup() {
Serial.begin(74880); //Serielle Schnittstelle initialisieren
//Pins für die Taster
pinMode(BTN1,INPUT_PULLUP);
pinMode(BTN2,INPUT_PULLUP);
Serial.println();
Serial.println("Start");
//DFPlayer vorbereiten
td.begin();
td.setVolume(25);
Serial.println("Sprachausgabe bereit");
td.setEnglish(false);
td.setWordTimeout(2);
//Callback Funktion registrieren
td.registerOnError(tdError);
//Sensor vorbereiten
bme.parameter.communication = 0; //Kommunikation über I2C
bme.parameter.I2CAddress = 0x76; //I2C Adresse
bme.parameter.sensorMode = 0x3; //kontinuierliche Messung
bme.parameter.IIRfilter = 0x04; //IIR Filter
bme.parameter.humidOversampling = 0x05; //Oversampling Luftfeuchtigkeit
bme.parameter.tempOversampling = 0x05; //Oversampling Temperatur
bme.parameter.pressOversampling = 0x05; //Oversampling Luftdruck
Serial.println(bme.init());
//Interne Uhr konfigurieren
configTime(MYTZ, NTP_SERVER);
//WLAN initialisieren und mit dem WLAN verbinden
uint8_t cnt = 0;
Serial.println("Netzwerkverbindung herstellen");
WiFi.persistent(false);
WiFi.mode(WIFI_STA);
WiFi.begin(STASSID, STAPSK);
//Auf Verbindung warten
while ((WiFi.status() != WL_CONNECTED) && (cnt<20)){
delay(500);
Serial.print(".");
cnt++;
}
Serial.println();
//Wenn die Verbindung erfolgreich war, wird die IP-Adresse angezeigt
if (WiFi.status() == WL_CONNECTED) {
Serial.print("IP-Adresse = ");
Serial.println(WiFi.localIP());
} else {
Serial.println("Keine Internetverbindung möglich");
}
}

//Hauptschleife
void loop() {
if (digitalRead(BTN1) == 0) {
//Zeit vorlesen
speak();
}
if (digitalRead(BTN2) == 0) {
//Zeit vorlesen
speakSensor();
}
td.loop();
}


Esquisse à télécharger

Contribution au format PDF

Voici un lien vers un Fichier MP3 afin que vous puissiez écouter le résultat

Amusez-vous avec l'horloge parlante.

 

 

 



Esp-32Projets pour les débutantsCapteurs

39 commentaires

Reimund

Reimund

Habe die Uhr nachgebaut. Scheint zu funktionieren. Allerdings ist die Sprachausgabe nicht komplett, sondern abgehackt. Wird nicht vollständig ausgesprochen.

Ist es richtig dass die MP3 Dateien direkt auf die SD Karte kopiert werden ? Also nicht im Ordner MP3 ?

Im Seriellen Monitor sehe ich folgendes.
ip-adresse = 192.168.178.97
wrong file type
device bussy
illegal argument

Reimund Konertz

Reimund Konertz

Es läuft nun einwandfrei. Aber kann man auch die Zeit zu jeder Stunde sprechen lassen, ohne einen Knopf zu drücken ?

Reimund

Reimund

Es klappt leider nicht. Bekomme die Meldung.

exit status 1
‘TZ_Europe_Berlin’ was not declared in this scope

Reimund

Reimund

Hallo kann man das auch so einstellen, dass jede Stunde eine Sprachausgabe erfolgt. So dass man keine Schalter braucht.. bzw. jede Stunde Sprachausgabe und wenn man den Schalter drückt, die aktuelle Uhrzeit.

Gerald Lechner

Gerald Lechner

Sie müssen nur in der Hauptschleife die Bedingung  
if (digitalRead(BTN1) == 0) {
   //Zeit vorlesen
   speak(); }
durch
time_t now = time(nullptr); //aktuelle Zeit
struct tm * s_time = localtime(&now);
if ((s_time→tm_min = 0) &&
(s_time→tm_sec = 0) &&
(s_time→tm_hour >= 8) &&
(s_time→tm_hour <= 23)) {
speak();
}
ersetzen.

Jozsef Majtenyi

Jozsef Majtenyi

Tolle Projekt!
Ich habe genau solche gewollt, nur mit eine kleine “Änderung” :)
Wie kann ich einstellen oder was muss ich umschreiben, dass ich nicht die Zeittaste drücken muss, sondern jeder 59:59 fangt an selber die eingestellte MP3s zu spielen? aber z.B von 23 – 5 Uhr Silent bleibt?
Vielen Dank voraus

Gerald Lechner

Gerald Lechner

Die Fehlermeldung “wrong stack” kommt vom DFPlayer und besagt, dass die serielle Kommunikation nicht richtig funktioniert. Die irrealen Werte des BMP280 deuten darauf hin, dass Takt- und Datenleitung entweder vertauscht sind oder eine der Leitungen fehlt. Dieser zweite Fehler hat aber nichts mit dem Problem zum DFPlayer zu tun.

ow

ow

wie muss ich den D1 in der Arduino-Ide zum Hochladen einstellen?
Er verbindet sich und ich erhalte eine ip. Danach erscheint im Seriellen-Monitor “wrong stack”. Beim drücken der Sensor-Taste erhalte ich utopische Werte: 141Grad, 0,0 Luftfeuchte. Nach dem Drücken der Uhrzeittaste erscheint im Seriellen-Monitor “wrong stack” und ab und an erfolgt die Sprach Ausgabe “Null”
Die Verdrahtung habe ich gefühlt tausendmal überprüft. Was mache ich falsch?
Gruß ow

Gerald Lechner

Gerald Lechner

Die Bibliothek Talking_Display ist vom verwendeten Mikrocontroller unabhängig funktioniert also nicht nur mit dem ESP8266 sonder n auch mit dem ESP32 oder irgend einem Arduino.

Jochen Ferger

Jochen Ferger

Hallo,
gibt es die Möglichkeit, die Bibliothek Talking_Display für einen ESP32 zu bekommen?
Viele Grüße
JOchen Ferger

Ralf Quest

Ralf Quest

Fehlermeldung “Illegal Argument” – Gelöst
Ich konnte die serielle Kommunikation zwischen NodeMCU und DFPlayer “belauschen” (PuTTY sei Dank) Es zeigte sich, dass die serielle Kommunikation ok war, lediglich die SD hatte ein Problem.
Etwas aussagekräftigere error codes werde ich noch in den code bauen…
Nette Idee, die “talking Clock”, vielen Dank

Ralf Quest

Ralf Quest

Fehlermeldung “Illegal Argument”:
Leider bekomme ich dieses Problem nicht gelöst, Es scheint als sei entweder mein MiniPlayer defekt oder sonst was ; hat jemand eine einfache Idee, wie ich die serielle Schnittstelle prüfen kann?

Bernd-Steffen Großmann

Bernd-Steffen Großmann

Hallo Pit, wie hier schon mehrfach geschrieben wurde: in der Zeile unter //Instanz für die Sprachausgabe fehlt nach „Talking_Display“ der Text „Software serial“ aber ohne Anführungszeichen sondern in spitzen Klammern – s. auch im ersten Sketch. Der funktioniert auch für den ESP8266 D1-Mini, wenn die Busy-Leitung auf GPIO13 gelegt wird und die Ergänzungen von Reiner eingefügt werden – die Rx und Tx- Belegung aber auf 12 und 14 belassen. Viele Grüße von Bernd-Steffen

Pit Richter

Pit Richter

Die erste Version von „Sprechende Uhr“ lief bei mir problemlos. Was mir nicht gefiel waren die Pausen von ca. 10s zwischen den Ansagen. Also Sonntag 10s – 14er-10s usw.
Bei der neuen Version mit Talking_Display td(ss,DFPLAYER_Busy);
oder jetzt
Talking_Display td(ss,BUSY);
Auch mit dem neuen Programm für D1
kommt immer dieser Fehler:
no matching function for call to ‘Talking_Display::Talking_Display(SoftwareSerial&, int)’ Finde keine Lösung für das Problem

Gerald Lechner

Gerald Lechner

Für alle, die die Busy-Leitung verwenden und den D1-Mini einsetzen möchten, hab ich eine Variante inklusive dem zugehörigen Sketch hinzugefügt.

Thomas

Thomas

Hier der Fix in der Talkind_Display.h, damit im 12h-Format-Ausgabe “12 Uhr…” statt “0 Uhr…” angesagt wird – ich hab einfach auf 0 abgefragt und platt auf 12 gesetzt:

//say a time using 24 hours and switching seconds off can be done by parameter void sayTime(struct tm * s_time, boolean h24 = true, boolean seconds = false) { uint16_t ampm = WORD_AM; uint8_t hour = s_time→tm_hour; if ((hour > 11) && (!h24)) { ampm = WORD_PM; hour = hour – 12;

//say 12 instead 0, if 12 hours is used and time between 12 and 1
if (hour == 0) {
hour = 12;
}

Horst Zeh

Horst Zeh

@Reiner
Text in spitzen Klammern wird in Kommentaren offenbar unterdrückt. In der Zeile:

Talking_Display td(ss,DFPLAYER_Busy);

fehlt deshalb nach “Talking_Display” der Text “SoftwareSerial” in spitzen Klammern. So wie es im Originalsketch steht.

Horst Zeh

Horst Zeh

@Reiner
Es sieht so aus, als ob in Kommentaren Text in spitzen Klammern unterdrückt wird (also einfach fehlt).
Die Zeile:

//Instanz für die Sprachausgabe
Talking_Display td(ss,DFPLAYER_Busy);

erzeugt einen Compilierfehler

//Instanz für die Sprachausgabe
Talking_Display td(ss,DFPLAYER_Busy);

ist korrekt.

Diesen Kommentar hatte ich schon vor Tagen abgegeben. Ist kommentarlos ignoriert worden.

Horst

Horst

Geht Text in spitzen Klammern in Kommentaren verloren?

Horst

Horst

@Reiner
Ist mir ein Rätsel, wie es zu ddiesem Schreibfehler kam. Hier nochmal:

//Instanz für die Sprachausgabe
Talking_Display td(ss,DFPLAYER_Busy);

erzeugt einen Compilierfehler

//Instanz für die Sprachausgabe
Talking_Display td(ss,DFPLAYER_Busy);

ist korrekt.

Horst

Horst

@Reiner

//Instanz für die Sprachausgabe
Talking_Display td(ss,DFPLAYER_Busy);

erzeugt einen Compilierfehler

//Instanz für die Sprachausgabe
Talking_Display td(ss,DFPLAYER_Busy);

ist korrekt.

Diesen Kommentar hatte ich schon vor Tagen abgegeben. Ist kommentarlos ignoriert worden.

Gerald Lechner

Gerald Lechner

Hallo hier noch einmal einHinweis zum Problem mit der Fehlermeldung “Illegal Argument”. Diese Fehlermeldung wird bei Kommunikationsproblemen über die serielle Schnittstelle zwischen Mikrocontroller und DFPlayer ausgelöst. Meist iist die Ursache eine Störung auf der Versorgungsspannung. Deshalb wurde auch bei der Schaltung der 1000µF Kondensator hinzugefügt.

Jochen Ferger

Jochen Ferger

Hallo,
ich bekomme ebenso nur Illegal Argument aus der Bibliothek.
WLAN-Verbindung steht, Port 123 wurde auf der Firewall freigegeben.

Wolfgang

Wolfgang

Hallo,
wie sieht der Sketch und die Pin Belegung für die Talking Clock aus für das Wemos D1 mini Board?
An welche Pins werden die Taster angeschlossen?

Claude

Claude

Hallo, bin Anfänger, hab alles soweit hinbekommen, aber ausser Geräusch ~~" shrep " " shrep " … ( 9xUhrzeit 17x Sensorwerte ) kommt kein Laut aus dem Lautsprecher !? Die einzelnen Mp3 files sind per io1 oder io2 ( Test ) abrufbar ?! bin echt am Verzweifeln und wäre für jede Hilfe dankbar :-)
mit besten Grüssen und vielen Dank !

Wolfgang

Wolfgang

Hallo Reiner,
wie hat die Hardware und der Sketch für das D1 mini Board auszusehen, wo werden die Taster angeschlossen?
Oder beim NodeMCU Lua Lolin V3,

Tom

Tom

Nach etwas tüfteln hat’s bei mir gestern Abend auch geklappt – und v.a. erst mit der Ergänzung von Reiner – ein großes Danke dafür!
Ich möchte damit eine kleine Box für meine Tochter bauen, auf der ich oben eine echte Uhr mit Zeigern montiere, damit sie die Uhrzeit spielerisch lesen, hören und lernen kann.
Heute Mittag wollte ich es ihr präsentieren und dabei ist mir aber eine Unschönheit aufgefallen. Ich hab zwei aufeinanderfolgende Ausgaben programmiert – eine für im 12h-Format und eine im 24h-Format. Bei der 12h-Format-Ausgabe kommt aber zwischen 12…13 Uhr eine Ausgabe von “0 Uhr Nachmittag”. Die 24h-Ausgabe ist korrekt. Kein Mensch sagt aber mittags “0 Uhr…”. :-(
Bekommt man das vielleicht gefixt, damit dann eine Ausgabe <12 Uhr Nachmittag" zu hören wäre?
Ansonsten nette Idee und ohne großem Aufwand schnell umzusetzen!

Horst

Horst

Hallo Reiner
Kleine Ursache – große Wirkung
.
//Instanz für die Sprachausgabe
Talking_Display td(ss,DFPLAYER_Busy);
.
müsste
.
//Instanz für die Sprachausgabe
Talking_Display td(ss,DFPLAYER_Busy);
.
lauten

Reiner

Reiner

Nachdem Gerald die Library jetzt auf 1.3 upgedated hat, funktioniert das Teil perfekt.
Für die Sprachausgabe fragt er die Busy Leitung vom DFPlayer ab. Die muss dann auch verbunden sein.
Der Sketch Talking clock muss dann wie folgt ergänzt werden:
Achtung … habe das Ganze für ein Wemos D1 mini Board angepasst …d.h. evtl. sind Eure Pins anders …

#define DFPLAYER_RX D3 //RX Anschluss für die Kommunikation mit dem DFPlayer
#define DFPLAYER_TX D4 //TX Anschluss für die Kommunikation mit dem DFPlayer
#define DFPLAYER_Busy D5 //Busy Anschluss vom DFPlayer
.
.
//Instanz für die Sprachausgabe
Talking_Display td(ss,DFPLAYER_Busy);
.
.
void setup () {
.
.
pinMode(DFPLAYER_Busy,INPUT);

Reiner

Reiner

Hallo Wolfgang,
hier musst Du Deine SSID und Dein Passwort für das WLAN eintragen …
//SSID und PSK vom lokalen WLAN
#define STASSID “****************”
#define STAPSK “****************”

Sternchen raus und SSID und Passwort rein ;-)

Markus

Markus

Schade: Was ich auch tue, ich erhalte immer nur “Illegal argument” aus der Library. Was läuft falsch? Hilfe wäre schön.

Horst

Horst

td.sayFloat(21.999,1); gibt “einundzwanzig Komma zehn” aus.
Wolfgang

Wolfgang

Hallo Rainer,
wo im Programmcode wird die die SSID und das Passwort eintragen, bin Anfänger.

Dieter

Dieter

Hallo Gerald, danke – jetzt funtioniert alles. :-)

Reiner

Reiner

via WLAN, einfach die SSID und das Passwort im Programmcode eintragen, dann verbindet sich der ESP mit dem Internet und holt die Zeit und das Datum

Wolfgang

Wolfgang

Wie wird eine Internet Verbindung mit dem ESP8266 hergestellt ,um die Uhrzeit zu bekommen?

Reiner

Reiner

Hi Dieter,
mach einen Update der Library. Gerald hat das schon gefixed …

Reiner

Reiner

Hallo Gerald,
erst mal Gratulation für die tolle Idee :-). Ich hätte da nur ein kleines Problem …
Der deutsche Teil funktioniert nicht … bei der Uhrzeit kommt nur …Sekunden .. sonst nichts.
Wenn ich die deutsche mp3 Dateien ins englische Direktory kopiere funktioniert es, abgesehen von der Reihenfolge mit Tag, Monat und Jahr. Passt aber von den Files.
Scheinbar stimmt etwas mit der Zerlegung nach EN/DE nicht … muss ich aber erst noch suchen …
beste Grüße
Reiner

Dieter

Dieter

Hallo, habe die Schaltung nachgebaut aber leider ein Problem. Initialisierung läuft, auch die IP Adresse erscheint. Nach drücken des Tasters ertönt aber nur das Wort “Sekunden”.
Wo könnte der Fehler liegen??
Vielen Dank

Laisser un commentaire

Tous les commentaires sont modérés avant d'être publiés

Messages de blogs recommandés

  1. Installez maintenant ESP32 via l'administrateur de la carte
  2. Lüftersteuerung Raspberry Pi
  3. Arduino IDE - Programmieren für Einsteiger - Teil 1
  4. ESP32 - das Multitalent
  5. OTA-Over the Air-ESP Programmation par WiFi